Whitespace bugs?

[andydude]

I only started using Wren yesterday, so I might have missed something in the docs. I was experimenting with OOP in Wren and I couldn't understand why all of the properties were always null! So I made a simple test case, and managed to figure out that it was the white-space that was causing the issue. I boiled it down to this code:

var b = Box.new(2)
System.print(b.x)

When this code is run with Box1, it works as expected, it prints 2. When this code is run with Box2, then it prints null. What exactly is happening here? Shouldn't Box2 work exactly the same as Box1?

Box 1

class Box1 {
    x { _x }
    x=(value) { _x = value }
    construct new(x) { _x = x }
}

Box 2

class Box2 {
    x { 
        _x 
    }
    
    x=(value) { 
        _x = value 
    }
    
    construct new(x) {
        _x = x
    }
}

[ruby0x1]

So the gotcha here is that "short hand return" is only valid if it's a single line.

x { _x } will return the contents of _x but the following will return null, which is the default in a method if nothing is returned by the end.

x {
  _x
  //implicit return null
}

what you're looking for is like this: because it's not a single line return shortcut, it must use the return keyword (otherwise it's just a "put the _x value on the stack and do nothing with it")

x {
  return _x
}

[ruby0x1]

the inverse is also invalid, e.g x { return _x } is an error because the return isn't expected in a single line early return like that ✨

[andydude]

Thank you for clarification.

[PureFox48]

This 'shorthand return' behavior is actually documented for functions but not (AFAICS) for methods.

I'll do a PR to fix that.