build.gradle

apply from: 'config/localprops.gradle'
apply from: 'config/keystore.gradle'

buildscript {
    repositories {
        jcenter()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:2.1.2'
        classpath 'com.github.dcendents:android-maven-gradle-plugin:1.3'
        classpath 'com.jfrog.bintray.gradle:gradle-bintray-plugin:1.7'
        classpath 'org.ajoberstar:gradle-git:1.5.0'
    }
}

subprojects {
    repositories {
        jcenter()

        maven {
            url "${rootProject.androidSdkDir}/extras/android/m2repository"
        }
    }
}

def grgit = org.ajoberstar.grgit.Grgit.open(dir: '.')
def lastCommit = grgit.head()

project.ext.versionNum = grgit.log(includes:['HEAD']).size()
project.ext.versionName = grgit.describe()
project.ext.versionDate = lastCommit.getDate()
if (project.ext.versionName == null) {
    project.ext.versionNme = 'DEV'
}

project.ext.minSdkVersion = 15
project.ext.compileSdkVersion = 24
project.ext.buildToolsVersion = '24.0.0'
project.ext.supportLibVersion = '24.0.0'

task showVersion << {
    logger.lifecycle("Version ID: " + project.versionNum)
    logger.lifecycle("Version Name: " + project.versionName)
    logger.lifecycle("Version Date: " + project.versionDate)
}

task wrapper(type: Wrapper) {
    gradleVersion = '2.14'
}