Fast rnd ported to DurexForth

[JoannaK]

And hi, new here. Simple and fast RND routine utilizing Sid chip.

\ Ref: https://www.atarimagazines.com/compute/issue72/random_numbers.php

\ sidrnd uses voice 3 noise generator,
\ may conflict with music playing routines

\ code sidini
\ $ff lda,# ( maximum frequency )
\ $d40e sta, ( v3 frequency low byte )
\ $d40f sta, ( v3 frequency high byte )
\ $80 lda,# ( noise wavef, gate off )
\ $d412 sta, ( voice 3 control register )
\ ;code

: sidini ( -- ) ( voice 3 max freq noise )
$ffff $d40e !
$80 $d412 c! ;

: sidrnd ( -- c ) ( return random byte )
$D41B c@ ;

[jkotlinski]

Hi Joanna, welcome! Thank you for sharing!

…

On Sun, 24 Oct 2021 at 13:49, JoannaK ***@***.***> wrote: And hi, new here. Simple and fast RND routine utilizing Sid chip. \ Ref: https://www.atarimagazines.com/compute/issue72/random_numbers.php \ sidrnd uses voice 3 noise generator, \ may conflict with music playing routines \ code sidini \ $ff lda,# ( maximum frequency ) \ $d40e sta, ( v3 frequency low byte ) \ $d40f sta, ( v3 frequency high byte ) \ $80 lda,# ( noise wavef, gate off ) \ $d412 sta, ( voice 3 control register ) \ ;code : sidini ( -- ) ( voice 3 max freq noise ) $ffff $d40e ! $80 $d412 c! ; : sidrnd ( -- c ) ( return random byte ) $D41B c@ ; — You are receiving this because you are subscribed to this thread. Reply to this email directly, view it on GitHub <#369>, or unsubscribe <https://github.com/notifications/unsubscribe-auth/AAY34O256FGDIJEWTRDGXK3UIPXC3ANCNFSM5GTL2LZA> . Triage notifications on the go with GitHub Mobile for iOS <https://apps.apple.com/app/apple-store/id1477376905?ct=notification-email&mt=8&pt=524675> or Android <https://play.google.com/store/apps/details?id=com.github.android&referrer=utm_campaign%3Dnotification-email%26utm_medium%3Demail%26utm_source%3Dgithub>.

[JoannaK]

No problem. Code may be bit flakey, I'm quite rusty on 6502/C64, been decades.

[Whammo]

It might be fun to use gfx.fs and PLOT to show the distribution of random numbers from the sid on the high res screen.

[JoannaK]

Whammo: Thank you for making TOD- timer routine. I have used it for testing code performance.

Would be interesting to see plot comparison. Sid randoms run independently so it'll be a bit more work to be sure test code captures all of them for plotting.

As fast and compact as sidrnd is, it also has some not so optimal aspects. For me the biggest is that there's no way (?) to seed the number generator and thus get repeatable sequences out of it for testing purposes.

Of generators I think suitable for small C64-forth, I see three main alternatives. Brodie's *+ as in rnd.fs, sidrnd as above and simple LFSR based generator. Rnd.fs is compact and reasonable fast but I have some suspicion of the randomness and coverage of 16bit number space. Sidrnd is even faster and as far as I know quite good rng-gen.

I have been tinkering with LFSR ramdom generator. I think my current version works, but at the moment it's written on Forth and slower than Brodies *+ routine that's in rnd.fs . In my own estimation it could be comparable or perhaps even a bit faster with asm.
https://www.xilinx.com/support/documentation/application_notes/xapp052.pdf

[Whammo]

Thanks for the acknowledgement. The TODs are, I think- the most useful but underutilized feature of the machine. Hopefully, at least on this platform, easy to use.
I don't know if you have seen this, but you should. :)
http://www.sidmusic.org/sid/sidtech5.html

[JoannaK]

Have not seen that one before. Interesting I have to say, and quite a lot work done to reverse engineering. So Sid has 23 bit LFSR with expected xor feedback at 23 and 18 so it is maximum length pattern 2^23 -1. Note though, that the lowest bit is numbered one at xilinx pdf, zero on sictech document.

Only real surprise is picking up 8 bits of random data from single shift/xor iteration. I'd expected it to iterate 8 times for 8 bits as that is more typical way. Sid approach is faster, and I'll expect it's good enough as long as user's dont' try to bulk capture continuous bytes and analyze them too closely.

Bellow is 15-bit lfsr protocode i wrote. May well be broken, but it seems to give random numbers :-)

variable slfsr

: lfsr1 ( -- b ) \ Return random bit
slfsr @
dup 2* tuck
xor
$4000 and
0= if 1 else
0 then
tuck
+ slfsr ! ;

: lfsrc ( - c ) \ Return random byte
0 8 0 do 2* lfsr1 + loop ;

: lfsr ( - n ) \ Return random int
0 16 0 do 2* lfsr1 + loop ;

: test 30 0 do lfsr . loop ;

[JoannaK]

Question: Is there need for 16 bit random numbers with 6502 based systeem? Asking cause lfsr takes closely N time for N-bits bit, so 8 bit routine is almost twice as fast as 16.

I did some testing on rnd results and the lowest bits of brodie-rnd are definitely not random at all.

hex
: testy3 200 0 do rnd $0f and . loop ;
decimal

Also did some visualization, only at text screen. This will be quite slow on real hw as is since test generates plenty random numbers. Two bytes of screen memory is used as a counter for each 8.bit random value. Good routine to compare speed of various routines.

: testy2 page
10 0 do -1 0 do rnd $ff and 2* screen +
dup @ 1+ swap ! loop loop
14 0 do cr loop
;

[Whammo]

These should speed things up a bit.

FAST blanks the screen and stops keyboard scan-

untested, but correct I think.

: irqpeek $dc0e c@ ;
: irqpoke $dc0e c! ;
: blvic $d011 dup c@ ;

: irqoff irqpeek $fe and irqpoke ;
: irqon irqpeek 1 or irqpoke ;
: blank blvic $ef and swap c! ;
: unblank blvic $10 or swap c! ;

: fast irqoff blank ;
: slow irqon unblank ;

[Whammo]

Or even:

: time parse-name elapsed evaluate ptod ;
$c000 time dump

[Whammo]

Even better:

 : time source >in @ /string 
dup >in +! elapsed evaluate
ptod ;
time $c000 dump
 

[Whammo]

Here's an exceptionally fast 10 print in forth with your RND routines.

: sidini ( -- )
$ffff $d40e !
$80 $d412 c! ;
                                                      \ JoannaK
: sidrnd ( -- c )
$D41B c@ ;

: doit do sidrnd 1 and if $4d i c!
else $4e i c! then loop ;              \ poke screen codes

: 10print 142 emit sidini            \ change case
2024 1024 doit                          \ whole screen
begin
1064 1024 960 move                 \ scroll screen
2024 1984 doit                          \ last line
key? until
key drop page 14 emit ;            \ cls, change case