NMI on a Commodore 64 using DurexForth

[Whammo]

NMI on Release v2.0.0.0,

from interpreter.asm

restore_handler  ; this is what the NMI vector points at instead of the kernal routine
    cli
    jmp QUIT

quit_reset ; NMI vector set  to restore_handler on startup and QUIT
    sei
    lda #<restore_handler ; * = $cdc
    sta $318
    lda #>restore_handler ; * = $ce1
    sta $319
    cli

Simply changing the NMI vector wouldn't work because QUIT resets the vector.
So, to enable RS-232, I employed a patch on quit_reset:

$FE47 $318 !  ; point NMI vector to  kernal routine
$FE $ce1 c!   ; change lda #<restore_handler to lda #<nmi handler
$47 $cdc c!   ; lda #>restore_handler to  lda #>nmi handler

Voila! We have RS-232. And side effects.

Note that any NMI not initiated by CIA 2 (RS-232)
is handled the same way as Restore key

This is Kernal source:

; nmi vector    *note 1*
lab_fe43
	sei				; disable the interrupts
	jmp	(lab_0318)		; do nmi vector


;************************************************************************************
;
; nmi handler

lab_fe47
	pha				; save a
	txa				; copy x
	pha				; save x
	tya				; copy y
	pha				; save y
	lda	#$7f			; disable all interrupts
	sta	lab_dd0d		; save via 2 icr
	ldy	lab_dd0d		; save via 2 icr
	bmi	lab_fe72		;.

	jsr	lab_fd02		; scan for autostart rom at $8000 * note 2 *
	bne	lab_fe5e		; branch if no autostart rom
	jmp	(lab_8002)		; else do autostart rom break entry * note 3*

lab_fe5e
	jsr	lab_f6bc		; increment real time clock
	jsr	lab_ffe1		; scan stop key                         *note 4*
	bne	lab_fe72		; if not [stop] restore registers and exit interrupt

; otherwise fall through to break vector- bad.

;************************************************************************************
;  
; *** this munges DurexForth***

; user function default vector
; brk handler

lab_fe66
	jsr	lab_fd15		; restore default i/o vectors
	jsr	lab_fda3		; initialise sid, cia and irq
	jsr	lab_e518		; initialise the screen and keyboard
	jmp	(lab_a002)		; do basic break entry

1: As long as the Kernal ROM is in context, this executes before jumping thru the NMI vector
2: On Restore key, this will restart DurexForth if booted from cart- bad.
3: this does the restart. We don't want this.
4: scan stop key
<> 0 Restore key only,
= 0 run/stop Restore

;************************************************************************************
;
; scan the stop key, return zb = 1 = [stop]

lab_f6ed
	lda	lab_91		; read the stop key column
	cmp	#$7f			; compare with [stp] down
	bne	lab_f6fa		; if not [stp] or not just [stp] exit

					; just [stp] was pressed
	php				; save status
	jsr	lab_ffcc		; close input and output channels * note 5
	sta	lab_c6		; save the keyboard buffer index
	plp				; restore status

lab_f6fa
	rts

5: This seems harmless enough

;************************************************************************************
;
; close input and output channels

lab_f333
	ldx	#$03			; set the screen device
	cpx	lab_9a		; compare the screen with the output device number
	bcs	lab_f33c		; if <= screen skip the serial bus unlisten

	jsr	lab_edfe		; else command the serial bus to unlisten
lab_f33c
	cpx	lab_99		; compare the screen with the input device number
	bcs	lab_f343		; if <= screen skip the serial bus untalk

	jsr	lab_edef		; else command the serial bus to untalk
lab_f343
	stx	lab_9a		; save the screen as the output device number
	lda	#$00			; set the keyboard as the input device
	sta	lab_99		; save the input device number
	rts

[Whammo]

; nmi handler

lab_fe47
	pha				; save a
	txa				; copy x
	pha				; save x
	tya				; copy y
	pha				; save y
	lda	#$7f			; disable all interrupts
	sta	lab_dd0d		; save via 2 icr
	ldy	lab_dd0d		; save via 2 icr
	bmi	lab_fe72		; The linchpin

So everything depends on whether or not the high bit is set on the read of $ddod, CIA 2 interrupt control register.
For compatibility's sake, we want QUIT to not reset the NMI vector, Restore key alone and any NMI including CIA 2 to carry on to $fe72 continuing the kernal NMI routines.
Run/stop Restore shall jmp QUIT. The only requirement for QUIT is a valid data stack pointer x.
IRQ vectoring leaves the return stack the same as the NMI vector, so brk vector is the same as
Run/stop Restore falling through.
This is the resultant code.

restore_handler
   pha				; save a
   txa				; copy x
   pha				; save x
   tya				; copy y
   pha				; save y
   lda	#$7f	    ; disable all interrupts
   sta	$dd0d       ; 
   ldy	$dd0d       ; save cia 2 icr
   bpl stop_restore ; if high bit not set

kernal_nmi
   jmp $fe72

stop_restore
   jsr $f6bc		; increment real time clock
                                ; scan stop key 
   lda $91 		; read the stop key column
   cmp #$7f		; compare with [stp] down
	        		; if not [stp] or not just [stp] exit
   bne kernal_nmi	; if not [stop] restore registers and exit interrupt


brk_handler
   pla
   pla
   tax              ; restore xr for QUIT
   jmp QUIT
   
quit_reset  ; execute once at start
    sei
    lda #<restore_handler
    sta $318
    lda #>restore_handler
    sta $319

    lda #<brk_handler
    sta $316
    lda #>brk_handler
    sta $317
    
keep_nmi
    cli ; still have to

Questions?

[Whammo]

This deserves reiteration.

The only requirement for QUIT is a valid data stack pointer x.

[Whammo]

The only requirement for jmp $fe72 the kernal NMI routine,
is:
ldy $dd0d
a read of cia 2 interrupt control register in y.

[Whammo]

QUIT on Release v2.0.0.0,

QUIT
    jsr quit_reset ; Changed to keep_nmi so as to not reset the NMI vector

    ; resets the return stack  *** preserve x ***
    txa
INIT_S = * + 1
    ldx #0
    txs
    tax          ; data stack pointer

interpret_loop
    jsr REFILL

    jsr interpret_tib
    jmp interpret_loop

[Whammo]

START on Release v2.0.0.0,
from durexforth.asm

This is unchanged but note how early in the program quit_reset is called.

; -------- program start

    lda 1
    pha
    lda $318
    pha
    lda $319
    pha
    tsx
    stx INIT_S  ; return stack initial condition QUIT resets it to this
    ldx #X_INIT ; data stack init

    jsr quit_reset   ; this now sets NMI and brk vectors once at startup and executes most of QUIT
                            ; but returns here to start forth
    jsr PAGE

    lda	#%00010110 ; lowercase
    sta	$d018

_START = * + 1
    jsr load_base

[Whammo]

#378