build.gradle

import java.text.SimpleDateFormat

buildscript {
    repositories {
        mavenCentral()
        jcenter()
    }
    dependencies {
        classpath 'be.jlr-home.gradle:plantumlPlugin:0.1.+'
        classpath 'com.bmuschko:gradle-nexus-plugin:2.+'
    }
}

apply plugin: 'java'
apply plugin: 'plantuml'
apply plugin: 'idea'
apply plugin: 'maven'
apply plugin: 'findbugs'
apply plugin: 'com.bmuschko.nexus'

sourceCompatibility = 1.8
targetCompatibility = 1.8

version     = projectVersion
group       = projectGroup
description = projectDescription

repositories {
    mavenLocal()
    mavenCentral()
}

dependencies {
    testCompile group: 'junit'              , name: 'junit'             , version: junitVersion
    compile     group: 'org.projectlombok'  , name: 'lombok'            , version: lombokVersion
    compile     group: 'ch.qos.logback'     , name: 'logback-classic'   , version: logbackVersion
}

jar {
    manifest {
        attributes( "Implementation-Title":         projectName,
                    "Implementation-Version":       projectVersion,
                    "Implementation-Vendor":        "Genoscope, LABGeM",
                    "Product-Name":                 projectName,
                    "provider":                     "Genoscope",
                    "Created-By":                   "LABGeM",
                    "description":                  projectDescription,
                    "Build-Date":                   new SimpleDateFormat("yyyy-MM-dd").format(new Date()),
                    "Build-JDK":                    System.getProperty("java.version"),
                    "Build-Gradle":                 project.gradle.gradleVersion
                   )
    }
    baseName = projectName
}

tasks.withType(JavaForkOptions) {
    jvmArgs  "-Dcom.sun.management.jmxremote.port=19988", "-Dcom.sun.management.jmxremote.ssl=false", "-Dcom.sun.management.jmxremote.authenticate=false", "-Ddrools.mbeans=enabled"
}

plantuml{
    fileFormat = 'SVG'
}

findbugs {
     effort = "max"
 }
 
modifyPom {
    project {
        name          projectName
        description   projectDescription
        url           projectUrlBase+projectUrlCore
        inceptionYear '2014'
        scm {
            url                   projectUrlBase+projectUrlCore
            connection            projectUrlBase+projectUrlCore+'.git'
            developerConnection   projectGitBase+projectUrlCore+'.git'
        }
        licenses {
            license {
                name          'CeCILL-C'
                url           'http://www.cecill.info/licences/Licence_CeCILL-C_V1-en.txt'
                distribution  'repo'
            }
        }
        developers {
            developer {
                id    'jmercier'
                name  'Jonathan MERCIER'
                email 'jmercier@genoscope.cns.fr'
            }
        }
    }
}

extraArchive {
     sources  = true
     tests    = true
     javadoc  = true
 }