Modifying Default VLAN 1 on Meraki MX with meraki_appliance_vlan

[wick1991]

Below is a part of the .tf file I am running to provision a meraki network. I am having trouble trying to modify VLAN1. This function attempts to create VLAN1 and gives me the error displayed at the bottom. I want to modify Default VLAN1

# Enable VLAN configurations on appliances in the Meraki Network "terraform1" 
resource "meraki_appliance_vlans_settings" "terraform1" {
  network_id    = meraki_network.terraform1.id
  vlans_enabled = true
}
 
# Configure VLAN interface with DHCP 
resource "meraki_appliance_vlan" "VLAN_20" {
   network_id                   = meraki_network.terraform1.id
   appliance_ip                 = "192.168.20.1"
   dhcp_boot_options_enabled    = false
   dhcp_handling                = "Run a DHCP server"
   dhcp_lease_time              = "12 hours"
   vlan_id                      = 20
   name                         = "Data VLAN 20"
   subnet                       = "192.168.20.0/24"
   ipv6_enabled                 = false
   mandatory_dhcp_enabled       = false
}

# HOW DO I MODIFY THE EXISTING VLAN 1? 
resource "meraki_appliance_vlan" "vlan_1" {
  network_id                   = meraki_network.terraform1.id    # Replace with your actual network ID
  vlan_id                      = 1            # VLAN 1, already exists
  appliance_ip                 = "192.168.1.1"  # Existing or updated appliance IP
  name                         = "Updated VLAN 1"  # Update the VLAN name
  subnet                       = "192.168.1.0/24"  # Update subnet as needed
  dhcp_handling                = "Run a DHCP server"  # Set the DHCP handling option
  dhcp_lease_time              = "12 hours"  # Update DHCP lease time
  ipv6_enabled                 = false  # Enable or disable IPv6
  mandatory_dhcp_enabled       = false   # Update this as needed
}

==========================
                     ERROR MESSAGE   
==========================
meraki_appliance_vlan.vlan_1: Creating...
╷
│ Error: Client Error
│ 
│   with meraki_appliance_vlan.vlan_1,
│   on resource.tf line 83, in resource "meraki_appliance_vlan" "vlan_1":
│   83: resource "meraki_appliance_vlan" "vlan_1" {
│ 
│ Failed to configure object (POST/PUT), got error: HTTP Request failed: StatusCode 400, JSON error: ["Vlan has already been taken"], {"errors":["Vlan has already been taken"]}
╵

I want to modify the DHCP scope of VLAN1 and the IP address of VLAN 1 on the MX appliance. What is the best function or method to accomplish this?

[danischm]

You would have to import the state of the resource first and then you can change it:

resource "meraki_appliance_vlan" "vlan_1" {
  network_id                   = meraki_network.test.id    # Replace with your actual network ID
  vlan_id                      = 1            # VLAN 1, already exists
  appliance_ip                 = "192.168.1.1"  # Existing or updated appliance IP
  name                         = "Updated VLAN 1"  # Update the VLAN name
  subnet                       = "192.168.1.0/24"  # Update subnet as needed
  dhcp_handling                = "Run a DHCP server"  # Set the DHCP handling option
  dhcp_lease_time              = "12 hours"  # Update DHCP lease time
  ipv6_enabled                 = false  # Enable or disable IPv6
  mandatory_dhcp_enabled       = false   # Update this as needed
}

import {
  to = meraki_appliance_vlan.vlan_1
  id = "${meraki_network.terraform1.id},1"
}

[danischm]

Did this answer your question?