keyhole 2D path

[lijon]

I wanted to make a keyhole shape, to make the kind of hole used to hang objects on the wall using a screw:

I wanted to specify the two radiuses, and be able to alter the distance between the two, and I wanted rounded corners. This was much more complicated than I thought, and this is the only way I came up with:

function keyhole(d1=3,d2=7,l=5,joint=1) = zrot(180, path_join([
    arc(d=d1,start=180,angle=180),
    [[0,0],[0,l]],
    reverse(slice(difference(circle(d=d2),rect([d1,d2],anchor=TOP))[0],end=-3)),
    [[0,l],[0,0]],
],joint=joint));

Can it be done in a simpler, more elegant way?

[lijon]

Here is another way which is cleaner I think:

function round_path(path, r, closed=true) = r==0 ? path : offset(offset(path,r,closed=closed),-r,closed=closed);

function keyhole(d1=3,d2=6,l,r,n=24) =
    let(r=default(r,d1/2),l=d2,$fn=n) // fn must be even for this to work!
    assert(r<d1)
    force_path(round_path(union([
        circle(d=d1),
        rect([d1,l],anchor=TOP),
        move([0,-l],circle(d=d2)),
    ]),r));

Unfortunately the existing round_corners() didn't work, so I made a simple round_path() using offset().

[revarbat]

I fleshed out a more complex version with error checking, which allows either circle to be the big one.

function keyhole(l, r1, r2, shoulder_r) =
    assert(is_num(l) && l>0)
    assert(is_num(r1) && r1>0)
    assert(is_num(r2) && r2>0)
    assert(l>=max(r1,r2))
    assert(is_undef(shoulder_r) || (is_num(shoulder_r) && shoulder_r>0))
    let(
        cp1 = [0,0],
        cp2 = cp1 + [0,-l],
        shoulder_r = is_num(shoulder_r)? shoulder_r : min(r1,r2) / 2,
        minr = min(r1, r2) + shoulder_r,
        maxr = max(r1, r2) + shoulder_r,
        dy = opp_hyp_to_adj(minr, maxr),
        spt1 = r1>r2? cp1+[minr,-dy] : cp2+[minr,dy],
        spt2 = [-spt1.x, spt1.y],
        ds = spt1 - (r1>r2? cp1 : cp2),
        ang = atan2(abs(ds.y), abs(ds.x)),
        path = r1>r2? [
                each arc(r=shoulder_r, cp=spt1, start=180-ang, angle=ang, endpoint=false),
                each arc(r=r2, cp=cp2, start=0, angle=-180, endpoint=false),
                each arc(r=shoulder_r, cp=spt2, start=0, angle=ang, endpoint=false),
                each arc(r=r1, cp=cp1, start=180+ang, angle=-180-2*ang, endpoint=false),
            ] : [
                each arc(r=shoulder_r, cp=spt1, start=180, angle=ang, endpoint=false),
                each arc(r=r2, cp=cp2, start=ang, angle=-180-2*ang, endpoint=false),
                each arc(r=shoulder_r, cp=spt2, start=360-ang, angle=ang, endpoint=false),
                each arc(r=r1, cp=cp1, start=180, angle=-180, endpoint=false),
            ]
    ) path;

[revarbat]

I've added keyhole() as a new shape in shapes2d.scad